u := 1.25cm;
r := 2.5pt;

beginfig(1);
z0=(0,0);
z1=(u,0);
z3=(0,1.5u);
z1-z0=z2-z1=z4-z3=z5-z4;
draw z1--z0--z4--z5--z1--z4;
draw z2--z3;
pickup pencircle scaled 2r;
for i=0 upto 5:  draw z[i];  endfor
label.top(btex$A$etex, z3+r*dir90);
label.top(btex$B$etex, z4+r*dir90);
label.top(btex$C$etex, z5+r*dir90);
label.bot(btex$D$etex, z0+r*dir-90);
label.bot(btex$E$etex, z1+r*dir-90);
label.bot(btex$F$etex, z2+r*dir-90);
endfig;

beginfig(2);
for i=0 upto 5:  z[i]=u*dir(90-60*i);  endfor
draw z0--z1--z2--z3--z5--z0--z3;
draw z1--z4--z2;
pickup pencircle scaled 2r;
for i=0 upto 5:  draw z[i];  endfor
label.top(btex$G$etex, z0+r*dir90);
label.urt(btex$H$etex, z1+r*dir30);
label.lrt(btex$I$etex, z2+r*dir-30);
label.bot(btex$J$etex, z3+r*dir-90);
label.llft(btex$K$etex, z4+r*dir-150);
label.ulft(btex$L$etex, z5+r*dir150);
endfig;

beginfig(3);
for i=0 upto 5: z[i]=u*dir(60*i);  endfor
z6=(0,u/3);
z7=(0,-u/3);
draw z0--z1--z6--z0--z5--z4--z3--z2..z2+u/3*dir120..z2--z6--z3--z7--z0;
pickup pencircle scaled 2r;
for i=0 upto 7:  draw z[i];  endfor
label.urt(btex$M$etex, z2+r*dir0);
label.top(btex$N$etex, z1+r*dir90);
label.top(btex$O$etex, z6+r*dir90);
label.lft(btex$P$etex, z3+r*dir180);
label.rt(btex$Q$etex, z0+r*dir0);
label.bot(btex$R$etex, z7+r*dir-90);
label.llft(btex$S$etex, z4+r*dir-120);
label.lrt(btex$T$etex, z5+r*dir-60);
endfig;

beginfig(4);
for i=0 upto 4:  z[i]=u*dir(90-72*i);  endfor
draw z0--z4--z1--z2--z3--z0--z2;
pickup pencircle scaled 2r;
for i=0 upto 4:  draw z[i];  endfor
label.top(btex$U$etex, z0+r*dir90);
label.rt(btex$V$etex, z1+r*dir0);
label.lrt(btex$W$etex, z2+r*dir-30);
label.llft(btex$X$etex, z3+r*dir-150);
label.lft(btex$Y$etex, z4+r*dir180);
endfig;

beginfig(5);
z0=(0,0);
z1=z0+u*dir-90;
z2=z4+2u/3*dir30;
z3=z1+u*dir-150;
z4=z1+u*dir-30;
z5=z2+u*dir-30;
z6=z7+u*dir180;
z7=z3+u*dir-90;
z8=z7+u*dir0;
z9=z4+2u/3*dir-90;
z10=z9+u*dir-30;
z11=z7+u*dir-90;
z12=z11+u*dir0;
draw z0--z1--z4--z2--z5--z10--z9--z4;
draw z1--z3--z7--z8--z12--z11--z7--z6;
pickup pencircle scaled 2r;
for i=0 upto 12:  draw z[i];  endfor
label.top(btex$a$etex, z0+r*dir90);
label.ulft(btex$b$etex, z3+r*dir150);
label.ulft(btex$c$etex, z1+r*dir150);
label.llft(btex$d$etex, z4+r*dir-150);
label.top(btex$e$etex, z2+r*dir90);
label.rt(btex$f$etex, z5+r*dir0);
label.lft(btex$g$etex, z6+r*dir180);
label.llft(btex$h$etex, z7+r*dir-135);
label.top(btex$i$etex, z8+r*dir90);
label.llft(btex$j$etex, z9+r*dir-90);
label.bot(btex$k$etex, z10+r*dir-90);
label.llft(btex$\ell$etex, z11+r*dir-135);
label.lrt(btex$m$etex, z12+r*dir-45);
endfig;

beginfig(6);
z0=(0,0);
z1=(1.5u,0);
z3=(0,-1.5u);
z1-z0=z3-z2=z4-z3=z5-z4=z7-z6=z9-z8;
z3-z0=z4-z1=z6-z3=z7-z4=z8-z6=z9-z7;
draw z0--z1--z5--z4--z0--z3--z1;
draw z0--z2--z3--z7--z4;
draw z5--z7--z9--z6--z7;
draw z2--z6--z8;
pickup pencircle scaled 2r;
for i=0 upto 9:  draw z[i];  endfor
label.top(btex$A$etex, z0+r*dir90);
label.top(btex$B$etex, z1+r*dir90);
label.lft(btex$C$etex, z2+r*dir180);
label.llft(btex$D$etex, z3+r*dir-135);
label.llft(btex$E$etex, z4+r*dir-135);
label.rt(btex$F$etex, z5+r*dir0);
label.llft(btex$G$etex, z6+r*dir-135);
label.lrt(btex$H$etex, z7+r*dir-45);
label.bot(btex$I$etex, z8+r*dir-90);
label.bot(btex$J$etex, z9+r*dir-90);
label.top("18", 0.5[z0,z1]);
label.ulft("7", 0.5[z0,z2]);
label.lft("5", 0.5[z0,z3]);
label.lrt("15", 0.75[z1,z3]);
label.urt("8", 0.75[z0,z4]);
label.urt("12", 0.5[z1,z5]);
label.bot("9", 0.5[z2,z3]);
label.top("19", 0.5[z4,z5]);
label.llft("20", 0.5[z2,z6]);
label.urt("6", 0.5[z3,z7]);
label.rt("3", 0.5[z4,z7]);
label.lrt("17", 0.5[z5,z7]);
label.top("25", 0.5[z6,z7]);
label.lft("14", 0.5[z6,z8]);
label.urt("21", 0.5[z6,z9]);
label.rt("10", 0.5[z7,z9]);
endfig;

beginfig(7);
for i=0 upto 4:  z[i]=2.5u*dir(90-72*i);  endfor
draw z0--z1--z2--z3--z4--z0--z2--z4--z1--z3--cycle;
pickup pencircle scaled 2r;
for i=0 upto 4:  draw z[i];  endfor
label.top(btex$V$etex, z0+r*dir90);
label.rt(btex$W$etex, z1+r*dir0);
label.lrt(btex$X$etex, z2+r*dir-30);
label.llft(btex$Y$etex, z3+r*dir-150);
label.lft(btex$Z$etex, z4+r*dir180);
label.urt("12", 0.5[z0,z1]);
label.urt("18", 0.5[z0,z2]);
label.ulft("30", 0.5[z0,z3]);
label.ulft("20", 0.5[z0,z4]);
label.lrt("10", 0.5[z1,z2]);
label.lrt("24", 0.5[z1,z3]);
label.top("9", 0.5[z1,z4]);
label.bot("15", 0.5[z2,z3]);
label.llft("13", 0.5[z2,z4]);
label.llft("26", 0.5[z3,z4]);
endfig;

bye