input TEX;

u:=0.7cm;
t:=1.5pt;
r:=2pt;

beginfig(1);
pickup pencircle scaled t;
drawdblarrow
for i=0 upto 100:
	if i>0: .. fi
	( (i/100)[-3.5u,7.5u], -3u*sind(90*(i/100)[-3.5,7.5]) )
endfor
;
pickup pencircle scaled 0.5;
drawarrow (-3.5u,0)--(7.5u,0);
drawarrow (0,-3.5u)--(0,3.5u);
picture l;
for i=-3 upto 7:
	if i<>0:
		draw (i*u,0)--(i*u,0.3u);
		l:=thelabel.bot(TEX("$\scriptstyle" & decimal(i) & "$"), (i*u,0));
		unfill bbox l;
		draw l;
	fi
endfor
for i=-3 upto 3:
	if i<>0:
		draw (0,i*u)--(0.3u,i*u);
		l:=thelabel.lft(TEX("$\scriptstyle" & decimal(i) & "$"), (0,i*u));
		unfill bbox l;
		draw l;
	fi
endfor
label.rt(btex$x$etex, (7.5u,0));
label.top(btex$y$etex, (0,3.5u));
endfig;

beginfig(2);
pickup pencircle scaled t;
drawdblarrow
for i=0 upto 100:
	if i>0: .. fi
	( (i/100)[-2.5u,6.5u], u*cosd(90*(i/100)[-2.5,6.5])+2u )
endfor
;
pickup pencircle scaled 0.5;
drawarrow (-2.5u,0)--(6.5u,0);
drawarrow (0,-1.5u)--(0,4.5u);
picture l;
for i=-2 upto 6:
	if i<>0:
		draw (i*u,0)--(i*u,0.3u);
		l:=thelabel.bot(
			if i=-2:      btex$-{\pi\over3}$etex
			elseif i=-1:  btex$-{\pi\over6}$etex
			elseif i=1:   btex$\pi\over6$etex
			elseif i=2:   btex$\pi\over3$etex
			elseif i=3:   btex$\pi\over2$etex
			elseif i=4:   btex$2\pi\over3$etex
			elseif i=5:   btex$5\pi\over6$etex
			elseif i=6:   btex$\pi$etex
			fi
			, (i*u,0));
		unfill bbox l;
		draw l;
	fi
endfor
for i=-1 upto 4:
	if i<>0:
		draw (0,i*u)--(0.3u,i*u);
		l:=thelabel.lft(TEX("$\scriptstyle" & decimal(i) & "$"), (0,i*u));
		unfill bbox l;
		draw l;
	fi
endfor
label.rt(btex$x$etex, (6.5u,0));
label.top(btex$y$etex, (0,4.5u));
endfig;

beginfig(3);
u:=2cm;
fill (0,0)--
	for i=0 step 8 until 32:  if i>0:  ..  fi  u*dir i  endfor
	--cycle withcolor 0.5[black,white];
draw  for i=0 step 10 until 350:  u*dir i..  endfor  cycle;
draw (0,0)--(2u,0)--(2u,1.25u)--cycle;
draw (1.85u,0)--(1.85u,0.15u)--(2u,0.15u);
drawdblarrow (0,-0.1u)--(2u,-0.1u);
label.bot(btex16 in.etex, 0.7[(0,-0.1u),(2u,-0.1u)]);
drawdblarrow ((0,0)+0.1u*dir(32+90))--(u*dir32+0.1u*dir(32+90));
label.ulft(btex8 in.etex, 0.5[((0,0)+0.1u*dir(32+90)),(u*dir32+0.1u*dir(32+90))]);
label.rt(btex10 in.etex, 0.5[(2u,0),(2u,1.25u)]);
endfig;

beginfig(4);
u:=2.5cm;
draw  for i=0 step 10 until 350:  u*dir i..  endfor  cycle;
pickup pencircle scaled t;
draw  for i=0 upto 10:  u*dir(360*i/11+90)--  endfor  cycle;
pickup pencircle scaled 0.5;
draw (0,0)--u*dir90;
label.rt("100", 0.5u*dir90);
endfig;

beginfig(5);
z0=(0,0);
z1=z0+3.5cm*dir15;
z2=z0+3cm*dir55;
draw z0--z1--z2--cycle;
label.lrt(btex$a$etex, 0.5[z0,z1]);
label(btex$A$etex, z2+0.3cm*dir-90);
label.ulft(btex$b$etex, 0.5[z0,z2]);
label(btex$B$etex, z1-0.45cm*dir(0.5[angle(z2-z1),angle(z0-z1)]));
label.urt(btex$c$etex, 0.5[z1,z2]);
label(btex$C$etex, z0+0.6cm*dir(0.5[angle(z1),angle(z2)]));
endfig;

beginfig(6);
u:=0.5cm;
z0=(0,0);
z1=z0+7u*dir0;
z2=z0+4u*dir58.81138;
draw z0--z1--z2--cycle;
label.bot("7", 0.5[z0,z1]);
label.ulft("4", 0.5[z0,z2]);
label.urt("6", 0.5[z1,z2]);
endfig;

bye